Скрипты для Trackinfo Panel

Список разделов Аудиоплеер foobar2000 Секреты foobar2000

Описание: Кнопочки, конфиги, секреты, советы.

Сообщение #21 Alex Jade » 16.06.2006, 10:41

В новой версии (0.8 для fb2k 0.9.2b5) не работает $char(1)!  :(
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #22 Elzor » 16.06.2006, 10:46

2Alex Jade зато превосходно работают $tab()
Люди не знают, что лисы умеют лазить по деревьям, если очень сильно захотят. Вот белки - те знают.
(с) П.Бигл
Elzor M
Мастер
Аватара
Возраст: 37
Откуда: г. Орск
Репутация: 1
С нами: 13 лет 4 месяца

Сообщение #23 Alex Jade » 16.06.2006, 15:02

Elzor писал(а):зато превосходно работают $tab()
$tab()=$char(1)R, а ;$char(1)C = ? :(
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #24 Rialto » 16.06.2006, 15:14

$tab()Текст,которых хотел выставить по центру$tab()
Rialto
Бывалый
Аватара
Репутация: 10
С нами: 13 лет 4 месяца

Сообщение #25 Alex Jade » 16.06.2006, 15:44

Rialto писал(а):$tab()Текст,которых хотел выставить по центру$tab()
Работает :) . Немного не логично %)
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #26 Maxim_289 » 02.07.2006, 13:13

Вот моё творчество:
Код: Выделить всё
//1 Column
$puts(1-Column-Theme,1)
$puts(1C,$select($get(1-Column-Theme),$rgb(53,62,120),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))
//2 Column
$puts(2-Column-Theme,1)
$puts(2C,$select($get(2-Column-Theme),$rgb(34,117,200),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))

//3 Column
$puts(3-Column-Theme,1)
$puts(3C,$select($get(3-Column-Theme),$rgb(37,126,216),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))
//4 Column
$puts(4-Column-Theme,1)
$puts(4C,$select($get(4-Column-Theme),$rgb(87,155,226),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))



$if(%isplaying%,$get(1C)Mode: BB7A02%_trackinfo_mode%$char(10),)

$if(%isplaying%, $transition($repeat(–,15),$rgb(170,205,240),$rgb(34,117,200))  $rgb(53,62,120)♪ $upper(Song info) ♪  $transition($repeat(–,15),$rgb(34,117,200),$rgb(170,205,240))$char(10),)

$if(%artist%,$get(1C)Artist: $get(2C)$caps(%artist%)$char(10),)
$if(%isplaying%,$get(1C)Album: $get(2C)$replace($if(%album%,%album%,%directoryname%),_, ,  ,)$char(10),)
$if(%title%,$get(1C)Title: $get(2C)$replace($caps(%title%),_, ,  ,)$char(10),)
$if(%date%,$get(1C)Date: $get(2C)%date%$char(10),)
$if(%genre%,$get(1C)Genre: $get(2C)%genre%$char(10),)
$if(%tracknumber%,$get(1C)Track Number: $get(2C)%tracknumber%$char(10),)
$if(%length%,$get(1C)Length: $get(2C)%length%$char(10),)


$if(%isplaying%,  $transition($repeat(–,15),$rgb(170,205,240),$rgb(34,117,200))   $rgb(53,62,120)● $upper(File info) ●   $transition($repeat(–,15),$rgb(34,117,200),$rgb(170,205,240))$char(10),)
$if(%isplaying%,$get(3C)Codec: $get(4C)$if(%codec%,%codec%,$ext(%path%))$char(10),)

$if(%isplaying%,$get(3C)Bitrate: $get(4C)%bitrate% kbps$char(10),)

$if(%isplaying%,$get(3C)Channels: $get(4C)$caps(%channels%)$char(10),)
$if(%isplaying%,$get(3C)Encoding type: $get(4C)$caps(%__encoding%)$char(10),)


$if(%isplaying%,$get(3C)Samplerate: $get(4C)%samplerate% Hz$char(10),)

$if(%isplaying%,$get(3C)ReplayGain: $get(4C)AG: $get(2C)%__replaygain_album_gain% $get(4C)TG: $get(2C)%__replaygain_track_gain%$char(10),)
$if(%__mp3_stereo_mode%,$get(3C)Stereo Mode: $get(4C)$caps(%__mp3_stereo_mode%)$char(10),)
$if(%__tagtype%,$get(3C)Tagtype: $get(4C)$replace($caps(%__tagtype%),'|',$get(4C) & $get(4C))$char(10),)
$puts(Filesize,$div(%_filesize%,1048576).$num($div($mul($mod(%_filesize%,1048576),100),1048576),2))
$if(%isplaying%,$get(3C)Filesize: $get(4C)$get(Filesize) MB$char(10))


$if(%isplaying%,   $transition($repeat(–,13),$rgb(170,205,240),$rgb(34,117,200)) $rgb(53,62,120)❙❙ $upper(Progress bar) ❙❙ $transition($repeat(–,13),$rgb(34,117,200),$rgb(170,205,240))$char(10),)

//$if(%isplaying%,$progress2(%playback_time_seconds%,%length_seconds%,48,737373'❙❙',D7D7D7'❙❙')$char(10),)
$puts(1,$transition($repeat('❙❙',$muldiv(48,%playback_time_seconds%,%length_seconds%)),3FAD7E,297454))
$puts(2,$transition($repeat('❙❙',$sub(48,$muldiv(48,%playback_time_seconds%,%length_seconds%))),$rgb(166,213,121),$rgb(195,233,152)))
$if(%isplaying%,$get(1)$get(2)$char(10),)

И вторая панель:
Код: Выделить всё
//1 Column
$puts(1-Column-Theme,1)
$puts(1C,$select($get(1-Column-Theme),$rgb(53,62,120),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))
//2 Column
$puts(2-Column-Theme,1)
$puts(2C,$select($get(2-Column-Theme),$rgb(34,117,200),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))

//3 Column
$puts(3-Column-Theme,1)
$puts(3C,$select($get(3-Column-Theme),$rgb(37,126,216),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))
//4 Column
$puts(4-Column-Theme,1)
$puts(4C,$select($get(4-Column-Theme),$rgb(87,155,226),$rgb(192,192,192),$rgb(164,164,164),$rgb(255,0,0)))

$puts(Line1,$transition($repeat(‒,16),$rgb(170,205,240),$rgb(34,117,200)))
$puts(Line2,$transition($repeat(‒,16),$rgb(34,117,200),$rgb(170,205,240)))

$if(%isplaying%,$get(2C)〚Filesize〛$tab()$get(Line1)$get(Line2)A8564A'〚'
$ifgreater(%_filesize%,30000000,▁ ▂ ▃ ▄ ▅ ▆ ▇ █,
$ifgreater(%_filesize%,26000000,▁ ▂ ▃ ▄ ▅ ▆ ▇$rgb(124,179,226) █,
$ifgreater(%_filesize%,22000000,▁ ▂ ▃ ▄ ▅ ▆$rgb(124,179,226) ▇ █,
$ifgreater(%_filesize%,18000000,▁ ▂ ▃ ▄ ▅$rgb(124,179,226) ▆ ▇ █,
$ifgreater(%_filesize%,14000000,▁ ▂ ▃ ▄$rgb(124,179,226) ▅ ▆ ▇ █,
$ifgreater(%_filesize%,10000000,▁ ▂ ▃$rgb(124,179,226) ▄ ▅ ▆ ▇ █,
$ifgreater(%_filesize%,6000000,▁ ▂$rgb(124,179,226) ▃ ▄ ▅ ▆ ▇ █,
$ifgreater(%_filesize%,2000000,▁$rgb(124,179,226) ▂ ▃ ▄ ▅ ▆ ▇ █,
))))))))A8564A'〛'$char(10),)


$if(%isplaying%,$get(2C)〚Bitrate Bar〛$tab()$get(Line1)$get(Line2)
$puts(low,E4A463)
$puts(med,A8564A)
$puts(high,$rgb(53,62,120))
$puts(Choose,$if($strcmp($info(bitrate),256),$get(med),$ifgreater($info(bitrate),256,$get(high),$get(low))))
$puts(3,$repeat('❙',$muldiv(26,$info(bitrate),1411)))
$puts(4,$repeat('·',$sub(26,$muldiv(26,$info(bitrate),1411))))
$if(%isplaying%,A8564A'〚'$get(Choose)$get(3)$get(4)A8564A'〛'$char(10),))

$if(%isplaying%,$get(4C)
$puts(low,E4A463)
$puts(med,A8564A)
$puts(high,$rgb(53,62,120))
$puts(Choose2,$if($strcmp($info(samplerate),44100),$get(med),$ifgreater($info(samplerate),44100,$get(high),$get(low))))
$puts(3,$repeat('❙',$muldiv(26,$info(samplerate),96000)))
$puts(4,$repeat('·',$sub(26,$muldiv(26,$info(samplerate),96000))))
$get(2C)〚Samplerate Bar〛$tab()$get(Line1)$get(Line2)$get(Choose2)'〚'$get(Choose2)$get(3)$get(4)$get(Choose2)'〛'$char(10),)

$if(%isplaying%,$get(2C)〚Channels〛$tab()$get(Line1)$get(Line2)$tab()A8564A'〚'$if($stricmp(%channels%,mono),①,$if($stricmp(%channels%,stereo),②,⑤.①))'〛'$char(10),)

Вот скрин моей темы: http://maxim-289.hotbox.ru/Blue.png
Maxim_289
Гость

Сообщение #27 Maxim_289 » 14.07.2006, 15:34

Код: Выделить всё
$puts(Cloud,E2E2E2)

$puts(Water1,
$repeat( ,34)00D7D7☼$char(10)
$get(Cloud)$repeat( ,1)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water2,
$repeat( ,35)00D7D7☼$char(10)
$get(Cloud)$repeat( ,9)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water3,
$repeat( ,34)00D7D7☼$char(10)
$get(Cloud)$repeat( ,19)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water4,
$repeat( ,36)00D7D7☼$char(10)
$get(Cloud)$repeat( ,26)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water5,
$repeat( ,34)00D7D7☼$char(10)
$get(Cloud)$repeat( ,33)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water6,
$repeat( ,35)00D7D7☼$char(10)
$get(Cloud)$repeat( ,40)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water7,
$repeat( ,36)00D7D7☼$char(10)
$get(Cloud)$repeat( ,47)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water8,
$repeat( ,35)00D7D7☼$char(10)
$get(Cloud)$repeat( ,54)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water9,
$repeat( ,34)00D7D7☼$char(10)
$get(Cloud)$repeat( ,61)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$puts(Water0,
$repeat( ,35)00D7D7☼$char(10)
$get(Cloud)$repeat( ,68)☁$char(10)
$rgb(2,122,187)$repeat(♒,20)$char(10))

$if(%isplaying%,
$if($strcmp($right(%playback_time_seconds%,1),1),$get(Water1),
$if($strcmp($right(%playback_time_seconds%,1),2),$get(Water2),
$if($strcmp($right(%playback_time_seconds%,1),3),$get(Water3),
$if($strcmp($right(%playback_time_seconds%,1),4),$get(Water4),
$if($strcmp($right(%playback_time_seconds%,1),5),$get(Water5),
$if($strcmp($right(%playback_time_seconds%,1),6),$get(Water6),
$if($strcmp($right(%playback_time_seconds%,1),7),$get(Water7),
$if($strcmp($right(%playback_time_seconds%,1),8),$get(Water8),
$if($strcmp($right(%playback_time_seconds%,1),9),$get(Water9),
$if($strcmp($right(%playback_time_seconds%,1),0),$get(Water0),
)))))))))))

А это - море с облаком и танцующим солнцем... :-)
Maxim_289
Гость

Сообщение #28 DruiD » 14.07.2006, 21:00

Maxim_289:
а что за шрифт используешь?
DruiD M
Автор темы, Мастер
Аватара
Возраст: 32
Откуда: Зеленоград
Репутация: 5
С нами: 13 лет 4 месяца

Сообщение #29 Maxim_289 » 18.07.2006, 14:05

DruiD
Arial Unicode MS
Лучше ставь 14 pt. и настрой Line spacing (-2 или -3)
Maxim_289
Гость

Сообщение #30 mgz » 16.08.2006, 04:20

Изображение
Панель foo_uie_trackinfo_mod.
Код:
Код: Выделить всё
// BG
$alignabs(,middle)$font(Arial,10,,100-100-100)
$transition(TIME TIME TIME TIME,$rgb(100,100,100),$rgb(130,130,255))$char(10)
$transition(TIME TIME TIME TIME,$rgb(100,100,100),$rgb(130,130,255))$char(10)
$transition(TIME TIME TIME TIME,$rgb(100,100,100),$rgb(130,130,255))$char(10)
$transition(TIME TIME TIME TIME,$rgb(100,100,100),$rgb(130,130,255))$char(10)
//
$alignabs(right,middle)$font(Arial,10,,100-100-100)
$transition(CODEC CODEC CODEC,$rgb(130,130,255),$rgb(100,100,100))$char(10)
$transition(CODEC CODEC CODEC,$rgb(130,130,255),$rgb(100,100,100))$char(10)
$transition(CODEC CODEC CODEC,$rgb(130,130,255),$rgb(100,100,100))$char(10)
$transition(CODEC CODEC CODEC,$rgb(130,130,255),$rgb(100,100,100))$char(10)
// -------------
//
$alignabs(right,middle)$font(Tahoma,7,shadow,150-150-255)
$if(%isplaying%,

$if2(%codec% ,)$if2($char(40)$caps($info(encoding))$char(41),)$char(10)
$if2($if($info(mp3_stereo_mode),$caps($info(mp3_stereo_mode)),$info(channels)),)$char(10)
$if2(%bitrate%kbps ,)$if($strcmp($upper($info(codec)),MP3),$if2($info(extrainfo),CBR),)$char(10)
$if2($div(%samplerate%,1000)$ifequal($div($mod(%samplerate%,1000),100),0,,.$div($mod(%samplerate%,1000),100))KHz,)$char(10)
$char(10)
$get(info)$div(1411,%__bitrate%).$substr($muldiv(1411,100,%__bitrate%),2,3):1 '('$get(info)$muldiv(%__bitrate%,100,1411)$get(anno)'%)'$char(10)
,)

$alignabs(,middle)$font(Impact,32,shadow,150-150-255)
  $if2(%_time_elapsed%,)

$font(Haettenschweiler,30,,)

$ifgreater($calcwidth(%artist% - %title%),%_width%
,$font(,22,shadow,)
,$font(,30,shadow,)
)
$align(center,middle)$rgb(150,150,255)
$if(%artist%,%artist% - ,)$if2(%title%,)

Не оптимизировано, не отточено... может кому пригодиЦЦа.
RME HDSP 9632 > DynAudio BM5A II / Audio-Technica ATH-AD900
Nexus 5 > Avantree Clipper > Sennheiser IE 4
mgz M
Гуру
Аватара
Возраст: 39
Откуда: Украина, Киев
Репутация: 73
С нами: 13 лет 4 месяца

Сообщение #31 iv_nik » 26.08.2006, 01:03

Изображение

Features:
  • Русский и английский;
  • 3 цветовые схемы для светлых и темных background'ов;
  • По сравнению с оригинальной (Mr. FreeZZZ) версией добалены некоторые новые строки, включая Last.FM Status, размер файла, определение VBR/ABR/CBR, и, если не забыл, progress bar;
  • По-умолчанию используется основной (простой) режим, которого вполне достаточно для большинства пользователей;
  • Полный список отображаемой информации см. на скриншоте.

Шрифт:
Tahoma bold 7pt

Код: Выделить всё
//Track Info Panel Formatted Strings v.1.1 by iv_nik (10.04.2006)
//Based on Track Info Panel Formatted Strings v.1.0 from Mr. FreeZZZ (08.02.2005 16:05)

// =============CONFIGURATION==============

// Language settings
// 1 - Russian, 2 - English
$puts(language,1)

//Color scheme settings
// 0 - Black (set the R-0,G-0,B-0 background color)
// 1 - White (set the R-255,G-255,B-255 background color)
// 2 - Creme (set the R-252,G-252,B-248 background color)
$puts(color_scheme,1)

//Showing strings
// 1- Show, 0 - Hide
//Song info part
$puts(s0,1)
//Artist
$puts(s1,1)
//Song
$puts(s2,1)
//Album
$puts(s3,1)
//Number of track
$puts(s4,1)
//Year
$puts(s5,1)
//Genre
$puts(s6,1)
//Rating
$puts(s7,0)
//Comment
$puts(s8,0)

//Show tech part
$puts(t0,1)
//Codec
$puts(t1,1)
//Bitrate
$puts(t2,1)
//Samplerate
$puts(t3,0)
//Channels
$puts(t4,0)
//Play count
$puts(t5,0)
//Last play date
$puts(t6,0)
//Time
$puts(t7,0)
//FileSize
$puts(t8,1)
//Last.FM
$puts(t9,1)
//Progress bar
$puts(t10,0)

// ======================================
// _CODE_SECTION_===========================

// _BLACK
$if($strcmp(0,$get(color_scheme)),
$puts(error_text_color,808080)
$puts(static_text_color,ffff80)
$puts(dynamic_text_color,ffffff)
$puts(section_color,00ff00)
$puts(plus_time_color,$blend($rgb(0,255,0),$rgb(255,255,0),%_time_elapsed%,%_time_total%))
$puts(minus_time_color,$blend($rgb(255,255,0),$rgb(0,255,0),%_time_elapsed%,%_time_total%))
,)
// _WHITE
$if($strcmp(1,$get(color_scheme)),
$puts(error_text_color,c0c0c0)
$puts(static_text_color,000000)
$puts(dynamic_text_color,400080)
$puts(section_color,804000)
$puts(plus_time_color,$blend($rgb(0,128,0),$rgb(255,0,0),%_time_elapsed%,%_time_total%))
$puts(minus_time_color,$blend($rgb(255,0,0),$rgb(0,128,0),%_time_elapsed%,%_time_total%))
,)
// _CREME
$if($strcmp(2,$get(color_scheme)),
$puts(error_text_color,c0c0c0)
$puts(static_text_color,408080)
$puts(dynamic_text_color,c08000)
$puts(section_color,404080)
$puts(plus_time_color,$blend($rgb(0,128,0),$rgb(255,0,0),%_time_elapsed%,%_time_total%))
$puts(minus_time_color,$blend($rgb(255,0,0),$rgb(0,128,0),%_time_elapsed%,%_time_total%))
,)

// Russian strings
$if($strcmp(1,$get(language)),
$puts(Song_Info,Информация о треке:)
$puts(Track_No_Present,Нет трека)
$puts(Artist,Исполнитель: )
$puts(Artist_Present,Неизвестный артист)
$puts(Title,Песня: )
$puts(Album,Альбом: )
$puts(Album_Present,Нет альбома)
$puts(Track,Номер: )
$puts(Is_Single,Сингл)
$puts(Date,Год: )
$puts(No_Date,Без даты)
$puts(Genre,Жанр: )
$puts(No_Genre,Неизвестно)
$puts(Rating,Оценка: )
$puts(Comment,Комментарий: )
$puts(Not_Rated,Без оценки)
$puts(No_Comment,Без комментария)

$puts(Technical,Техническая информация: )
$puts(Codec,Кодек: )
$puts(Bitrate,Битрейт: )
$puts(kbps, Кб/c)
$puts(Samplerate,Частота сэмплов: )
$puts(Hz, кГц)
$puts(Channels,Каналы: )
$puts(played,Эта песня играла )
$puts(times, раз'('а')')
$puts(Last,Последний раз: )
$puts(at,в )
$puts(Never, Никогда)
$puts(Time,Время: )
$puts(total,всего )
$puts(filesize,Размер файла: )
$puts(lastfm,Last.FM: )
$puts(submitted,Отправлено)
$puts(pending,Ожидание...),)


// English strings
$if($strcmp(2,$get(language)),
$puts(Song_Info,Song Info:)
$puts(Track_No_Present,No Track)
$puts(Artist,Artist: )
$puts(Artist_Present,Unknown Artist)
$puts(Title,Title: )
$puts(Album,Album: )
$puts(Album_Present,Unknown Album)
$puts(Track,Track: )
$puts(Is_Single,Single)
$puts(Date,Date: )
$puts(No_Date,Unknown Date)
$puts(Genre,Genre: )
$puts(No_Genre,No Genre)
$puts(Rating,Rating: )
$puts(Comment,Comment: )
$puts(Not_Rated,No Rated)
$puts(No_Comment,No comment)

$puts(Technical,Technical Info: )
$puts(Codec,Codec: )
$puts(Bitrate,Bitrate: )
$puts(kbps, kbps)
$puts(Samplerate,Samplerate: )
$puts(Hz, kHz)
$puts(Channels,Channels: )
$puts(played,This song was played )
$puts(times, times)
$puts(Last,Last played: )
$puts(at,at )
$puts(Never, Never)
$puts(Time,Time: )
$puts(total,total )
$puts(filesize,File Size: )
$puts(lastfm,Last.FM Status: )
$puts(submitted,Submitted)
$puts(pending,Pending...)
,)


$if($strcmp(1,$get(s0)),
$get(section_color)$get(Song_Info)$char(10)
$if(%_trackinfo_notrack%,$get(error_text_color)$get(Track_No_Present)$char(10),

$if($strcmp(1,$get(s1)),
$get(static_text_color)$get(Artist)
$get(dynamic_text_color)
$if2($caps(%artist%),$get(error_text_color)$get(Artist_Present))
$char(10)
,)

$if($strcmp(1,$get(s2)),
$get(static_text_color)$get(Title)
$get(dynamic_text_color)
$if2($caps(%title%),%_filename%)
$char(10)
,)

$if($strcmp(1,$get(s3)),
$get(static_text_color)$get(Album)
$get(dynamic_text_color)
$if2($caps(%album%),$get(error_text_color)$get(Album_Present))
$char(10)
,)

$if($strcmp(1,$get(s4)),
$get(static_text_color)$get(Track)
$get(dynamic_text_color)
$if2(%tracknumber%,$get(Is_Single))
$char(10)
,)

$if($strcmp(1,$get(s5)),
$get(static_text_color)$get(Date)
$get(dynamic_text_color)
$if2(%date%,$get(error_text_color)$get(No_Date))
$char(10)
,)

$if($strcmp(1,$get(s6)),
$get(static_text_color)$get(Genre)
$get(dynamic_text_color)
$if2(%Genre%,$get(error_text_color)$get(No_Genre))
$char(10)
,)

$if($strcmp(1,$get(s7)),
$get(static_text_color)$get(Rating)
$get(dynamic_text_color)
$if2(%Rating%,$get(error_text_color)$get(Not_Rated))
$char(10)
,)

$if($strcmp(1,$get(s8)),
$get(static_text_color)$get(Comment)
$get(dynamic_text_color)
$if2(%Comment%,$get(error_text_color)$get(No_Comment))
$char(10)
,)
$char(10)
),)

/////////////////////////////////////////////////////////////////////////////////////////////////

$if($strcmp(1,$get(t0)),
$get(section_color)$get(Technical)$char(10)
$if(%_trackinfo_notrack%,$get(error_text_color)$get(Track_No_Present)$char(10),

$if($strcmp(1,$get(t1)),
$get(static_text_color)$get(Codec)$get(dynamic_text_color)$codec()$if($stricmp($codec(),MP3),[ %__extrainfo%])
$char(10)
,)

$if($strcmp(1,$get(t2)),
$get(static_text_color)$get(Bitrate)$get(dynamic_text_color)$if(%__extrainfo%,~,)%__bitrate%$get(static_text_color)$get(kbps)
$char(10)
,)

$if($strcmp(1,$get(t3)),
$get(static_text_color)$get(Samplerate)$get(dynamic_text_color)$div(%__Samplerate%,1000)','$cut($mod(%__Samplerate%,1000),1)$get(static_text_color)$get(Hz)
$char(10)
,)

$if($strcmp(1,$get(t4)),
$get(static_text_color)$get(Channels)
$get(dynamic_text_color)%__channels% $if(%__mp3_stereo_mode%, '('%__mp3_stereo_mode%')',)
$char(10)
,)

$if($strcmp(1,$get(t5)),
$get(static_text_color)$get(played)$get(dynamic_text_color)$if(%play_counter%,%play_counter%,0)$get(static_text_color)$get(times)
$char(10)
,)

$if($strcmp(1,$get(t6)),
$get(static_text_color)$get(Last)$get(dynamic_text_color)$if(%play_date%,%play_date% $get(static_text_color)$get(at)$get(dynamic_text_color)%play_time%,$get(Never))
$char(10)
,)

$if($strcmp(1,$get(t7)),
$get(static_text_color)$get(Time)
$if(%_isplaying%,$get(plus_time_color)%_time_elapsed% $get(static_text_color)| $get(dynamic_text_color)%_time_total% $get(static_text_color)$get(static_text_color)| $get(minus_time_color)%_time_remaining%$get(static_text_color),$get(dynamic_text_color)%_length%)
$char(10)
,)

$if($strcmp(1,$get(t8)),
$get(static_text_color)$get(filesize)$get(dynamic_text_color)$div(%_filesize%,1048576).$left($num($muldiv($mod(%_filesize%,1048576),100,1048576),2),2)$get(static_text_color)' MB'
$char(10)
,)

$if($strcmp(1,$get(t9)),
$get(static_text_color)$get(lastfm)$get(dynamic_text_color)$if(%_isplaying%,
$ifgreater(%_time_elapsed_seconds%,240,$get(submitted),
$ifgreater(%_time_elapsed_seconds%,$div(%_time_total_seconds%,2),$get(submitted),$get(pending))))
$char(10)
,)

$char(10)
$if($strcmp(1,$get(t10)),
$progress(%_time_elapsed_seconds%, %_time_total_seconds%, 25,400080'|',9a9a9a'-'),)
),)
Последний раз редактировалось iv_nik 26.08.2006, 18:37, всего редактировалось 1 раз.
iv_nik
Новичок
Репутация: 0
С нами: 13 лет 4 месяца

Сообщение #32 Deskoul » 07.11.2006, 23:25

Перевод строки в коментариях выдаёт какойто неопознаный символ, это можно както побороть? Хелп!!!  :-[

Изображение
Deskoul M
Новичок
Возраст: 42
Откуда: Киев Украина
Репутация: 0
С нами: 12 лет 10 месяцев

Сообщение #33 100100010011 » 21.11.2006, 15:07

2iv_nik:
включая Last.FM Status
А где этот код??? Нужна только эта функция...
Последний раз редактировалось DruiD 21.11.2006, 19:39, всего редактировалось 1 раз.
100100010011
Гость

Сообщение #34 100100010011 » 21.11.2006, 15:12

2iv_nik, и еще...можно ли такой же прогресс бар как у клиента last.fm? или хотябы Remaining Time в Trackinfo видеть как в их клиенте???!!! :-[

Кто знает?
Последний раз редактировалось DruiD 21.11.2006, 19:39, всего редактировалось 1 раз.
100100010011
Гость

Сообщение #35 DruiD » 21.11.2006, 19:38

0100100010011 писал(а):А где этот код??? Нужна только эта функция...
Чуть ниже в окошке код :)
$if($strcmp(1,$get(t9)),
$get(static_text_color)$get(lastfm)$get(dynamic_text_color)$if(%_isplaying%,
$ifgreater(%_time_elapsed_seconds%,240,$get(submitted),
$ifgreater(%_time_elapsed_seconds%,$div(%_time_total_seconds%,2),$get(submitted),$get(pending))))
$char(10)
,)

0100100010011 писал(а):и еще...можно ли такой же прогресс бар как у клиента last.fm?
Кто знает?
а какой он там? скрин дай.

ps. Оформляй посты попроще, иначе приму меры.
DruiD M
Автор темы, Мастер
Аватара
Возраст: 32
Откуда: Зеленоград
Репутация: 5
С нами: 13 лет 4 месяца

Сообщение #36 100100010011 » 21.11.2006, 20:15

Понял. :-[

http://img377.imageshack.us/img377/5411/1qq1.jpg
Тот код показывает "Ожидание" и "Отправлено". Былоб удобнее если показывалось в Trackinfo и "Remaining Time" до scrobblинга или как на картинке...Возможно ли это?...
100100010011
Гость

Сообщение #37 Alex Jade » 03.12.2006, 22:43

Мой скрипт для Trackinfo Panel:
Код: Выделить всё
[%genre%][ ◉ %style%]$tab()$if(%isplaying%,$tab()[$max(0,$left($muldiv(%playback_time_seconds%,1000,%length_seconds%),$sub($len($muldiv(%playback_time_seconds%,1000,%length_seconds%)),1)))'.'$right($muldiv(%playback_time_seconds%,1000,%length_seconds%),1)'%']' ◉ ')[%length%][ - %playback_time_remaining% =][ %playback_time%][ ◉ x%play_count%]$char(10)
$tab()$rgb(255,0,0)[%artist%]$tab()$char(10)
$tab()$rgb(255,255,0)[%album%]$tab()$char(10)
$tab()$rgb(255,255,0)[$if2(%date%,%year%)]$tab()$char(10)
$tab()$rgb(0,255,0)[[%disc%.]%tracknumber%[/%trackcount%]: ][$meta(title,0)]$tab()$char(10)
$tab()$rgb(0,0,255)[%remix%]$tab()$char(10)
$char(10)
$tab()
$select(%rating%,
$rgb(0,0,255)★,
$rgb(0,0,255)★★,
$rgb(0,255,0)★★★,
$rgb(0,255,0)★★★★,
$rgb(255,255,0)★★★★★,
$rgb(255,255,0)★★★★★★,
$rgb(255,0,0)★★★★★★★,
$rgb(255,0,0)★★★★★★★★,
$rgb(255,255,255)★★★★★★★★★)
$tab()$char(10)
$tab()[%composer%]$tab()$char(10)
$tab()$if3(G: %game%,M: %movie%,)$tab()$char(10)
$if(%_isplaying%,$ifgreater(%_time_elapsed_seconds%,240,'*', $ifgreater(%_time_elapsed_seconds%,$div(%_time_total_seconds%,2),'*',)))
[$if2(%__replaygain_track_gain%,No) TG ◉ $if2(%__replaygain_album_gain%,No) AG][ ◉ $if(%lyrics%,L)]$tab()[[%__bitrate_dynamic%◈]%__bitrate%[◈%__bitrate_nominal%] kbps][ ◉ %__samplerate% hz ◉ %__channels% ch][ ◉ %__codec%]
Скриншоты:
Изображение  Изображение
Используемые теги (кроме стандартных):
%composer% - композитор.
%style% - стиль (используется совместно с %genre%).
%movie%, %game% - в каких фильмах/играх можно услышать проигрываемый трек.
%rating% - рейтинг (1>8>9)
%remix% - название ремикса
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #38 Alex Jade » 03.12.2006, 22:54

Ещё один скрипт. Модификация предыдущего для трекинфо панели меньших размеров.
Код: Выделить всё
$if(%isplaying%,
$tab()$rgb(255,0,0)[%artist%]$tab()$char(10)
$tab()$rgb(255,255,0)[%album%]$tab()$char(10)
$tab()$rgb(255,255,0)[$if2(%date%,%year%)]$tab()$char(10)
$tab()$rgb(0,255,0)[[%disc%.]%tracknumber%[/%trackcount%]: ][$meta(title,0)]$tab()$char(10)
$tab()$rgb(0,0,255)[%remix%]$tab()$char(10)
$char(10)
$tab()
$select(%rating%,
$rgb(0,0,255)★,
$rgb(0,0,255)★★,
$rgb(0,255,0)★★★,
$rgb(0,255,0)★★★★,
$rgb(255,255,0)★★★★★,
$rgb(255,255,0)★★★★★★,
$rgb(255,0,0)★★★★★★★,
$rgb(255,0,0)★★★★★★★★,
$rgb(255,255,255)★★★★★★★★★)
$tab()$char(10)
$tab()[%genre%][ ◉ %style%]$tab()$char(10)
$tab()[%composer%]$tab()$char(10)
$tab()$if3(G: %game%,M: %movie%,)$tab()$char(10)
$char(10)
$tab()[$max(0,$left($muldiv(%playback_time_seconds%,1000,%length_seconds%),$sub($len($muldiv(%playback_time_seconds%,1000,%length_seconds%)),1)))'.'$right($muldiv(%playback_time_seconds%,1000,%length_seconds%),1)'%']' ◉ ')[%length%][ - %playback_time_remaining% =][ %playback_time%][ ◉ x%play_count%]$tab()$char(10)
$tab()[$if2(%__replaygain_track_gain%,No) TG ◉ $if2(%__replaygain_album_gain%,No) AG][ ◉ $if(%lyrics%,L)]$tab()$char(10)
$tab()[[%__bitrate_dynamic%◈]%__bitrate%[◈%__bitrate_nominal%] kbps][ ◉ %__samplerate% hz ◉ %__channels% ch][ ◉ %__codec%]$tab()
Скриншоты:
Изображение Изображение
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Скрипты для Trackinfo Panel: Таймер

Сообщение #39 Alex Jade » 28.12.2006, 10:17

Нестандартный скрипт для Trackinfo Panel. Выводит таймер отсчитывающий время указанного (в данном случае до нового года  :) )
Параметры: d - день текущего месяца, если конечная дата находится в следующем месяце, то складываем кол-во дней в этом месяце и дату в следующем (в примере 1 января = 31+1 ). h - часы, m - минуты, s - секунды.
Также необходимо наличие плагина foo_cwb_hooks.
Код: Выделить всё
$puts(d,32)
$puts(h,22)
$puts(m,30)
$puts(s,0)

$puts(day,$num($substr(%cwb_systemdatetime%,9,10),1))
$puts(hour,$num($substr(%cwb_systemdatetime%,12,13),1))
$puts(minute,$num($substr(%cwb_systemdatetime%,15,16),1))
$puts(second,$num($substr(%cwb_systemdatetime%,18,20),1))

$puts(time,$add($mul($get(day),86400),$mul($get(hour),3600),$mul($get(minute),60),$get(second)))
$puts(t,$add($mul($get(d),86400),$mul($get(h),3600),$mul($get(m),60),$get(s)))

$puts(dx,$sub($get(t),$get(time)))

$puts(hx,$num($div($get(dx),3600),2))
$puts(mx,$num($div($mod($get(dx),3600),60),2))
$puts(sx,$num($mod($mod($get(dx),3600),60),2))

$tab()$ifgreater($get(dx),0,$get(hx):$get(mx):$get(sx),00:00:00)$tab()$char(10)
P.S. Если во время простоя плеера таймер не отображается, кликните дважды по панельке. Должно работать.
P.P.S. Скрипт пока не работает с промежутками более чем 2 месяца - 1 день.
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Скрипты для Trackinfo Panel: бегущая строка v2.2

Сообщение #40 Exoulum » 07.01.2007, 00:33

Доброго времени суток! Хочу сказать спасибо Dr.Death'у за сборку. Собственно в процессе её подгонки под свою коллекцию и сделал нижеследующий скрипт.
У меня слова песен всегда хранятся в тегах, да и требования к оформлению этих самых тегов довольно строгие, поэтому среди прочего сделал украшение Trackinfo: добавил туда бегущую строку состоящую из текста песни.
Движется она по тексту пропорционально ползунку прогрессбара. На наличие слов проверяются теги %unsyncedlyrics%, %unsynced lyrics% (стандартные TagScanner'овские) и %lyrics% ,%lyric% (стандартные для плагина отображения текста песен).
Изначально скрипт планировался как чисто декоративный (для отображения лирики у меня отдельная вкладка Trackinfo), но в процессе наблюдения оказалось, что вокал довольно часто попадает в эту строку независимо от композиции  :)
Код: Выделить всё
//Поиск слов в тегах
$puts(lyr,[$if3(%unsyncedlyrics%,%unsynced lyrics%,%lyrics%,%lyric%)])

//Удаление "мусора" в окончании строк (возврат каретки) и перевода строки
$puts(lyr,$replace($get(lyr),$char(13)$char(10),'  '))

//Длина бегущей строки
$puts(bsl,30)

//Позиция в тексте
$puts(ptxt,$max(0,$muldiv(%playback_time_seconds%,$sub($len($get(lyr)),$get(bsl)),%length_seconds%)))

//Вывод
$get(t2)'Lyrics: '$get(t3)$if3(...$substr($get(lyr),$get(ptxt),$add($get(ptxt),$get(bsl)))...,'найти и добавить!')$char(10)
$get(t3) и $get(t2) можно выкинуть - это элемент оформления и работает только в конкретной сборке.
Функция $muldiv для меня до сих пор загадка. Вернее как она работает понятно - не понятно почему, ибо в документации не описана (взял её из другого скрипта той же сборки).
А выглядит это так: http://i145.photobucket.com/albums/r215/Exoulum/bs.jpg
P.S. Если что я тут первый раз, так что ногами сильно не бейте.  :-[

UPD.
Deskoul писал(а):Перевод строки в коментариях выдаёт какойто неопознаный символ, это можно както побороть? Хелп!!!  :-[

Изображение
У меня в скрипте этот символ вместе с переводом каретки убирает
Код: Выделить всё
 $replace($get(lyr),$char(13)$char(10),'  ')
, если перевод каретки убирать не нужно, то
Код: Выделить всё
$replace($get(lyr),$char(13),)
, где $get(lyr) надо поменять на %comment% или другой текст, где производится замена.
UPD 10.03.09 Давно не пользовался, а тут попобовал — не заработало. Убил час времени и нашёл в чём дело: чтобы заработало в новых версиях Track Info Panel Mod в начале конфигурации надо добавить строку «// PerSecond», для следующей версии также справедливо.
Последний раз редактировалось Exoulum 10.03.2008, 23:59, всего редактировалось 1 раз.
Exoulum
Новичок
Репутация: 0
С нами: 12 лет 8 месяцев

Пред.След.

Вернуться в Секреты foobar2000