Скрипты для Trackinfo Panel

Список разделов Аудиоплеер foobar2000 Секреты foobar2000

Описание: Кнопочки, конфиги, секреты, советы.

Сообщение #41 Urh » 07.01.2007, 06:50

2Exoulum, классно реализовано, мне только с этого момента и понравился многострочный trackinfo!

Ах да, музыкальный вкус тоже хорош... :)
«Я построю свой луна-парк с блекджеком и шлюхами...»
Urh M
Бывалый
Аватара
Откуда: Blackwater Park
Репутация: 1
С нами: 12 лет 9 месяцев

Сообщение #42 Exoulum » 07.01.2007, 13:51

2Urh Спасибо, только жаль рывками работает, а миллисекунд воспроизведения насколько понял не бывает. Заменил скрипт в предыдущем сообщении (поменял монструозный поиск по тегам на поприличнее и упростил позицию в тексте), работает также.
Последний раз редактировалось Exoulum 07.01.2007, 14:14, всего редактировалось 1 раз.
Exoulum
Новичок
Репутация: 0
С нами: 12 лет 8 месяцев

Скрипты для Trackinfo Panel: Бегущая строка (blend) v 2.0

Сообщение #43 Exoulum » 07.01.2007, 17:57

Немного доработал свой скрипт: мне не понравились троеточия в начале и в конце.
Теперь строка по краям смешивается с фоном и выглядит так: http://i145.photobucket.com/albums/r215/Exoulum/bsbv.jpg
Код: Выделить всё
//Поиск слов в тегах
$puts(lyr,[$if3(%unsyncedlyrics%,%unsynced lyrics%,%lyrics%,%lyric%)])

//Удаление "мусора" в окончании строк (возврат каретки) и перевода строки
$puts(lyr,$replace($get(lyr),$char(13)$char(10),'  '))

//Длина бегущей строки
$puts(bsl,30)
//Цвет текста и цвет фона
$puts(tcol,$rgb(255,255,255))$puts(bcol,$rgb(46,48,63))

//Начальная позиция в тексте
$puts(ptxt,$max(0,$muldiv(%playback_time_seconds%,$sub($len($get(lyr)),$get(bsl)),%length_seconds%)))

//Выделяю строку в тексте
$puts(lyr,$substr($get(lyr),$get(ptxt),$add($get(ptxt),$get(bsl))))

//Вывод
$get(t2)'Lyrics: '$get(t3)$if3(
 $transition($left($get(lyr),$div($len($get(lyr)),2)),$get(bcol),$get(tcol))
$transition($right($get(lyr),$div($add($len($get(lyr)),1),2)),$get(tcol),$get(bcol))
 ,'найти и добавить!')$char(10)
Последний раз редактировалось Exoulum 08.01.2007, 17:14, всего редактировалось 1 раз.
Exoulum
Новичок
Репутация: 0
С нами: 12 лет 8 месяцев

Сообщение #44 Alex Jade » 09.01.2007, 14:35

Exoulum писал(а):миллисекунд воспроизведения насколько понял не бывает
Не бывает. Миллисекунды есть в длине трека:
Код: Выделить всё
%length_ex%
Заодно приведу пример кода форматирующего длину трека к 00:00:00.000:
Код: Выделить всё
$select($len(%length%),00:00:0,00:00:,00:00,00:0,00:,00,0,)%length_ex%
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #45 Baka Neko » 06.02.2007, 14:38

Как определить, есть ли в файле title? По идее должно работать:
Код: Выделить всё
$if(%title%,$get(color_main)%title%,$get(color_badtitle)%filename%)
Но %title% возвращает либо непосредственно тайтл, либо имя файла, если тайтл не обнаружен. А нужно чтоб он возвращал false (ну или как там в фубаре).
Boku wa baka, nya!
Baka Neko M
Новичок
Аватара
Возраст: 32
Откуда: Братск
Репутация: 0
С нами: 12 лет 10 месяцев

Сообщение #46 Mishail » 06.02.2007, 15:57

Mishail M
Мастер
Аватара
Возраст: 39
Репутация: 5
С нами: 13 лет 4 месяца

Сообщение #47 Baka Neko » 06.02.2007, 16:42

Ну я ступил, блин :) Спасибо большое
Boku wa baka, nya!
Baka Neko M
Новичок
Аватара
Возраст: 32
Откуда: Братск
Репутация: 0
С нами: 12 лет 10 месяцев

Сообщение #48 iv_nik » 08.02.2007, 15:42

0100100010011 писал(а):2iv_nik, и еще...можно ли такой же прогресс бар как у клиента last.fm? или хотябы Remaining Time в Trackinfo видеть как в их клиенте???!!! :-[
Отправка осуществляется на середине трека, если я правильно понимаю. Наверное, не сложно сделать )
iv_nik
Новичок
Репутация: 0
С нами: 13 лет 4 месяца

Сообщение #49 DruiD » 03.03.2007, 17:08

Отправка осуществляется на середине трека,
на середине, либо после 4 минут проигрывания. Но смысла не вижу, так как не учитываются возможные проблемы при передаче, перемотка трэка и тд. Вот если бы плагин устанавливал переменные тогда было б другое дело.
DruiD M
Автор темы, Мастер
Аватара
Возраст: 32
Откуда: Зеленоград
Репутация: 5
С нами: 13 лет 4 месяца

Сообщение #50 Zalexi » 11.03.2007, 00:57

2Exoulum
Как ты прописал в скрипте "Tool" что у тебя показывает чем закодировано, а также "Bitrate", "Tags Type" и "Channels"?
Zalexi M
Новичок
Возраст: 49
Откуда: Spain
Репутация: 0
С нами: 13 лет 4 месяца

Сообщение #51 Alex Jade » 11.03.2007, 02:36

Zalexi писал(а):в скрипте "Tool"  а также "Bitrate", "Tags Type" и "Channels"
%__tool% = чем закодировано
%bitrate% = текущий битрейт (равен %__bitrate_dynamic% для воспроизводимого трека и %__bitrate% для остальных)
%__bitrate% = средний битрейт композиции (для VBR), битрейт композиции (для CBR)
%__bitrate_dynamic% = текущий битрейт (только для воспроизводимого трека)
%__bitrate_nominal% = номинальный битрейт (только для кодека Vorbis (*.ogg))
%channels% = кол-во каналов (Mono, Stereo, либо число каналов, если более 2х)
%__channels% = кол-во каналов (всегда число)
%__tagtype% = типы тегов, присутствующие в файле (отсутствует у *.ogg)
Последний раз редактировалось Sp1ke 16.03.2007, 00:57, всего редактировалось 1 раз.
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #52 B3ND3R » 14.03.2007, 21:04

я уже чего только не читал, но как мне сделать, чтобы у меня в Trackinfo Panel обновлялась инфа? у меня как стоит на 0 процентов в прогрессбаре или время 0:00, и все, сама не обновляется, мож где галочку поставить надо?
B3ND3R
Новичок
Репутация: 0
С нами: 12 лет 10 месяцев

Сообщение #53 Alex Jade » 15.03.2007, 00:18

B3ND3R писал(а):в Trackinfo Panel обновлялась инфа?
Update every second

Track Info Mod обновляется автоматически (в последней версии этого почему то не происходит! Изображение).
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #54 Zalexi » 16.03.2007, 00:25

2 Alex 'AJ' Jade
Попробовал, но tool так и не показывает, в 8 версии это еще зависело от модифицированой foo_input_std.dll, может, и здесь так же?
Zalexi M
Новичок
Возраст: 49
Откуда: Spain
Репутация: 0
С нами: 13 лет 4 месяца

Сообщение #55 Alex Jade » 16.03.2007, 00:55

2 Zalexi
Ошибочка вышла Изображение Tool = %__tool%. Данный тег может отсутствовать в файле (например в MP3). Всегда присутствует в Ogg Vorbis файлах.
Изображение Изображение
Alex Jade M
Бывалый
Возраст: 34
Откуда: Мурманск
Репутация: 2
С нами: 13 лет 4 месяца

Сообщение #56 PaVliG » 04.05.2007, 14:51

Поставил некий скрипт с гидры от автора Lycox

http://wiki.hydrogenaudio.org/index.php?title=Foo ... Info_Panel_(foo_uie_trackinfo)

Скррипт уже двухлетней давности и в 0.9.4.3 фубаре + TrackInfo Panel 0.8 не отображается строка LAME Version and Profile, все файлы VBR он определяет как CBR. А также подскажите пожалуйста, как модифицировать код, чтобы в строке Channels в случае if каналов 2 отображался конкретный стерео-режим (joint-stereo, stereo)? (Или же, как будет выглядеть подобная строка отдельно под строкой Channels, пусть она называется Stereo-Mode?)

Вот оригинальный текст:

Код: Выделить всё
//////////////////////////////
// Highly customizeable track information
// Author: Lycox
// Version 0.8
// Comments to: lycox@material-base.net
// Web: http://www.material-base.net
//////////////////////////////

//////////////////////////////
// Changelog:
//////////////////////////////

// + = Added / - = Removed / * = Fixed / # = Changed

// v0.8
// + Enable/Disable progressbar

// v0.7
// + added support for foo_cwb_hooks (Active Playlist)

// v0.6
// + readded support for foo_playcount unofficial
// + readded First-Played Tag
// - Natural Language Timestamps (because it doesn't work)

// v0.5
// + New Section: User Info
// # Replaygain moved to User Info
// # Albumgain moved to User Info
// # First-Played moved to User Info
// # Last-Played moved to User Info
// # Rating moved to User Info
// # Play-Counter moved to User Info
// # Switch between Date-Format and Natural Language Timestamps (Default)

// v0.4
// + PlayCounter: First_Played-Tag (Default Off)
// + PlayCounter: Last_Played-Tag
// + Customizeable PlayCounter date format
// + WWW-Tag
// * Code cleanup
// * updated to work with columns_ui (06/04/28)

// # Updated to new PlayCounter-Tags
// # Spacer (Thanks Erich w/ an h)

// v0.3
// + Color-Schemes

// v0.2
// + DISC-Tag (DISCNUMBER-Tag)
// + TRACK-Tag
// + FEATURING-Tag
// + Extra Info on Codec
// + Dynamic Bitrate
// + LAME Version and Profile
// + Musepack Profile
// + Bitdepth for lossless formats
// + STYLE-Tag
// + Truncate Multirow Comments

// * Filesize
// * small bug fixes

//////////////////////////////
// Credits:
// Peter Pawlowski for great fb2k
// Free - for great progressbar
// upNorth - for filesize string / Bugfixed Version from Forum
// Looks quite good with Arial, 8pt bold
//////////////////////////////

// ==============================================

//////////////////////////////
// Global Config Part //
//////////////////////////////

//////////////////////////////
// Color schemes
// 0 = Standard, 1 = HmmXP, 2 = Custom
//////////////////////////////

// Set the colorscheme
$puts(color_scheme,1)

// Standard
// Background (255,255,255)
$if($strcmp(0,$get(color_scheme)),
$puts(headline,256d3d)
$puts(info,ec9184)
$puts(text,000000)
$puts(grayed,c8c8c8)
$puts(playing_mode,DCAE8D)
$puts(add,888888)
$puts(spacer_color,d6d6d6)
// Colors for progressbar
$puts(progress_color1,ff6d66)
$puts(progress_color2,ffe1df))

// HmmXP
// Background (235,232,227) or (247,244,241)
$if($strcmp(1,$get(color_scheme)),
$puts(headline,B7A38A)
$puts(info,856551)
$puts(text,4C4C4C)
$puts(grayed,909090)
$puts(playing_mode,B7A38A)
$puts(add,9BA3A7)
$puts(spacer_color,d6d6d6)
// Colors for progressbar
$puts(progress_color1,856551)
$puts(progress_color2,E3E8EB))

// Custom
// Background (255,255,255)
$if($strcmp(2,$get(color_scheme)),
$puts(headline,256d3d)
$puts(info,ec9184)
$puts(text,000000)
$puts(grayed,c8c8c8)
$puts(playing_mode,DCAE8D)
$puts(add,888888)
$puts(spacer_color,d6d6d6)
// Colors for progressbar
$puts(progress_color1,ff6d66)
$puts(progress_color2,ffe1df))

//////////////////////////////
// Enable/Disable Progressbar
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_progressbar,1)

//////////////////////////////
// Shows Song Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_songinfo,1)

//////////////////////////////
// Show various informations in Song Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(title,1)
$puts(artist,1)
$puts(featuring,1)
$puts(mixartist,1)
$puts(band,1)
$puts(album,1)
$puts(tracknumber,1)
$puts(disc,1)
$puts(genre,1)
$puts(style,1)
$puts(bpm,1)
$puts(date,1)
$puts(copyright,1)


//////////////////////////////
// Shows Additional Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_additionalinfo,1)

//////////////////////////////
// Show various informations in Additional Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(comment,1)
// Use this to shorten Multirow Comments
$puts(comment_short,1)
$puts(comment_length,297)

$puts(www,1)
$puts(wwwartist,1)
$puts(publisher,1)
$puts(language,1)
$puts(composer,1)
$puts(lyricist,1)
$puts(conductor,1)
$puts(recordingdates,1)
$puts(fileowner,1)



//////////////////////////////
// Shows User Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_userinfo,1)

//////////////////////////////
// Show various informations in User Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(trackgain,1)
$puts(albumgain,1)
$puts(rating,1)
$puts(play_counter,1)
$puts(first_played,0)
$puts(last_played,1)

// Set date format
// 1 = DD/MM/YYYY
// 2 = MM/DD/YYYY
// 3 = YYYY/MM/DD
// 4 = YYYY/DD/MM
$puts(first_played_scheme,1)
$puts(last_played_scheme,1)

// Show first/last played time
$puts(first_played_scheme_time,1)
$puts(last_played_scheme_time,1)


//////////////////////////////
// Shows Technical Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_techinfo,1)

//////////////////////////////
// Show various informations in Tech Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(codec,1)
$puts(extra_info,1)
$puts(bitrate,1)
$puts(samplerate,1)
// Switch between Hz and kHz (default OFF)
$puts(samplerate_short,1)
$puts(lame_version,1)
$puts(lame_profile,1)
$puts(mpc_profile,1)
$puts(bitdepth,1)
$puts(channels,1)
$puts(time_elapsed_total,1)

$puts(encodedby,1)
$puts(encodersettings,1)
$puts(filesize,1)
// hidden, because not really needed
$puts(filename_ext,0)
$puts(mediatype,0)
$puts(size,0)
$puts(songlen,0)
$puts(time,0)


//////////////////////////////
// Shows Web Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_webinfo,1)

//////////////////////////////
// Shows Web Related Infos in Web Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_webrelated,1)

//////////////////////////////
// Show various informations in Web Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(www,1)
$puts(wwwaudiofile,1)
$puts(wwwcopyright,1)
$puts(wwwcommercialinfo,1)
$puts(wwwpayment,1)
$puts(wwwpublisher,1)
$puts(wwwuser,1)

//////////////////////////////
// Shows NetRadio Info in Web Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_netradioinfo,1)

//////////////////////////////
// Show various informations in NetRadio Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(wwwradiopage,1)
$puts(netradioowner,1)
$puts(netradiostation,1)


//////////////////////////////
// Shows Misc Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_miscinfo,1)

//////////////////////////////
// Show various informations in Misc Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(subtitle,1)
$puts(involvedpeople,1)
$puts(playlistdelay,0)
$puts(initialkey,0)
$puts(isrc,0)
$puts(partinset,0)


//////////////////////////////
// Shows Original Info in track info panel
// 0 = No, 1 = Yes
//////////////////////////////
$puts(show_originalinfo,1)

//////////////////////////////
// Show various informations in Original Info
// 0 = No, 1 = Yes
//////////////////////////////
$puts(origartist,1)
$puts(origyear,1)
$puts(origlyricist,1)
$puts(origfilename,1)

//////////////////////////////
// Define chars
// Show here: http://eolindel.free.fr/foobar0.9/customize.shtml
//////////////////////////////
// Define rating char
$puts(rating_char,$char(9679))
// Define spacer char
$puts(spacer_char,-)
// Define progressbar char
$puts(progress_char,$char(9679))
// Set length of the progressbar
$puts(progress_length,25)


//////////////////////////////
// Spacer
//////////////////////////////
$puts(spacer_length,90)

// Don't change this line
$puts(spacer,$get(spacer_color)$repeat($get(spacer_char),$get(spacer_length))$char(10))

////////////////////////////////
// End Global Config Part //
////////////////////////////////
// ==============================================

//////////////////////////////
// Show Playing Mode
//////////////////////////////

$get(playing_mode)Mode: %_trackinfo_mode% $if(%cwb_activelist%,'('%cwb_activelist%')')$char(10)$if(%_trackinfo_notrack%,$get(grayed)'['No track']'$char(10),

// progressbar config
$puts(theme,1)

$if($strcmp($get(theme),1),
$puts($get(progress_color1))
$puts($get(progress_color2))
)


//////////////////////////////
// PREPARE COLOR-STRINGS
//////////////////////////////
$puts(progress_color1a,$blend($get(progress_color1),000000,1,4.5))
$puts(progress_color2a,$blend($get(progress_color2),000000,1,5.7))

// progressbar
$puts(progressbar,
$if(%_length_seconds%,

$puts(progress,$muldiv(%_time_elapsed_seconds%,$get(progress_length),%_length_seconds%))
$transition($repeat($get(progress_char),$get(progress)),$get(progress_color1a),$get(progress_color1))
$transition($repeat($get(progress_char),$sub($get(progress_length),$get(progress))),$get(progress_color2a),$get(progress_color2))
$get(text)$pad_right($muldiv(%_time_elapsed_seconds%,100,%_length_seconds%),3)'%'
,streaming...
))

$if($strcmp(1,$get(show_progressbar)),$get(progressbar)$char(10))
)
//////////////////////////////
// Song Info
//////////////////////////////
$if($strcmp(1,$get(show_songinfo)),
$get(spacer)
$tab()$get(headline)Song Info$tab()$char(10)
$if($strcmp(1,$get(title)),$get(info)Title: $get(text)$if($meta(title),$meta(title),$get(grayed)'['No Title']')$char(10))
$if($strcmp(1,$get(artist)),$get(info)Artist: $get(text)$if($meta(artist),$meta(artist),$get(grayed)'['Unknown Artist']') )
$if($strcmp(1,$get(featuring)),$if($meta(featuring),$get(add)feat. $get(text)$meta(featuring))$char(10))
$if($strcmp(1,$get(mixartist))
|$strcmp(1,$get(band))
,
$if($strcmp(1,$get(mixartist)),$if($meta(remixed by),$get(info)Remixed by: $get(text)$meta(remixed by)$char(10)))
$if($strcmp(1,$get(band)),$if($meta(band),$get(info)Band: $get(text)$meta(band)$char(10))))
$if($strcmp(1,$get(album)),$if($meta(album),$get(info)Album: $get(text)$meta(album)$char(10)))

$if($strcmp(1,$get(tracknumber)),$if($meta(tracknumber)|$meta(track),$get(info)Track: $get(text)$if($meta(tracknumber),$meta(tracknumber),$meta(track)) $if($strcmp(1,$get(disc)),$if($meta(disc)|$meta(discnumber),$get(grayed)'('$if($meta(disc),$meta(disc),$meta(discnumber))')'))$char(10),$if($meta(disc)|$meta(discnumber),$get(info)Disc: $get(text)$if($meta(disc),$meta(disc),$meta(discnumber))$char(10))))
$if($strcmp(0,$get(tracknumber)),$if($meta(disc)|$meta(discnumber),$get(info)Disc: $get(text)$if($meta(disc),$meta(disc),$meta(discnumber))$char(10)))


$if($strcmp(1,$get(genre)),$if($meta(genre),$get(info)Genre: $get(text)$meta(genre)$char(10)))

$if($strcmp(1,$get(style)),
$if($meta(style),$get(info)Style: $get(text)$meta(style)$char(10))
$if($meta(styles),$get(info)Style: $get(text)$meta(styles)$char(10)))

$if($strcmp(1,$get(bpm)),$if($meta(bpm),$get(info)bpm: $get(text)$meta(bpm)$char(10)))
$if($strcmp(1,$get(date)),$if($meta(date),$get(info)Date: $get(text)$meta(date)$char(10)))
$if($strcmp(1,$get(copyright)),$if($meta(copyright),$get(info)© $get(text)$meta(copyright)$char(10)))
)
// End Song Info

//////////////////////////////
// Additional Info
//////////////////////////////
$if($strcmp(1,$get(show_additionalinfo)),
$if($if(%comment%,$and($strcmp(1,$get(comment))))
|$if(%www%,$and($strcmp(1,$get(www))))
|$if(%wwwartist%,$and($strcmp(1,$get(wwwartist))))
|$if(%publisher%,$and($strcmp(1,$get(publisher))))
|$if(%language%,$and($strcmp(1,$get(language))))
|$if(%composer%,$and($strcmp(1,$get(composer))))
|$if(%lyricist%,$and($strcmp(1,$get(lyricist))))
|$if(%conductor%,$and($strcmp(1,$get(conductor))))
|$if(%recordingdates%,$and($strcmp(1,$get(recordingdates))))
|$if(%fileowner%,$and($strcmp(1,$get(fileowner))))
,$get(spacer)
$tab()$get(headline)Additional Info$tab()$char(10)

$if($strcmp(1,$get(comment)),$if($meta(comment),$get(info)Comment: $get(text)$if($strcmp(1,$get(comment_short)),
$iflonger($replace($meta(comment),$char(13),),$get(comment_length),
$cut($replace($meta(comment),$char(13),),$sub($get(comment_length),5))'(...)',
$replace($meta(comment),$char(13),)),
%comment%)$char(10)))

$if($strcmp(1,$get(www)),$if($meta(www),$get(info)WWW: $get(text)$meta(www)$char(10)))
$if($strcmp(1,$get(wwwartist)),$if($meta(wwwartist),$get(info)Web: $get(text)$meta(wwwartist)$char(10)))
$if($strcmp(1,$get(publisher)),$if($meta(publisher),$get(info)Publisher: $get(text)$meta(publisher)$char(10)))
$if($strcmp(1,$get(language)),$if($meta(language),$get(info)Language: $get(text)$meta(language)$char(10)))
$if($strcmp(1,$get(composer)),$if($meta(composer),$get(info)Composer: $get(text)$meta(composer)$char(10)))
$if($strcmp(1,$get(lyricist)),$if($meta(lyricist),$get(info)Lyricist: $get(text)$meta(lyricist)$char(10)))
$if($strcmp(1,$get(conductor)),$if($meta(conductor),$get(info)Conductor: $get(text)$meta(conductor)$char(10)))
$if($strcmp(1,$get(contentgroup)),$if($meta(contentgroup),$get(info)Group: $get(text)$meta(contentgroup)$char(10)))
$if($strcmp(1,$get(recordingdates)),$if($meta(recordingdates),$get(info)Rec. Date: $get(text)$meta(recordingdates)$char(10)))
$if($strcmp(1,$get(fileowner)),$if($meta(fileowner),$get(info)Owner: $get(text)$meta(fileowner)$char(10)))
))
// End Additional Info



//////////////////////////////
// User Info
//////////////////////////////
$if($strcmp(1,$get(show_userinfo)),
$if($if(%__replaygain_track_gain%,$and($strcmp(1,$get(trackgain))))
|$if(%__replaygain_album_gain%,$and($strcmp(1,$get(albumgain))))
|$if(%rating%,$and($strcmp(1,$get(rating))))
|$if(%play_counter%,$and($strcmp(1,$get(play_counter))))
|$if(%first_played%,$and($strcmp(1,$get(first_played))))
|$if(%last_played%,$and($strcmp(1,$get(last_played))))
|$if(%lyricist%,$and($strcmp(1,$get(lyricist))))
|$if(%conductor%,$and($strcmp(1,$get(conductor))))
|$if(%recordingdates%,$and($strcmp(1,$get(recordingdates))))
|$if(%fileowner%,$and($strcmp(1,$get(fileowner))))
,$get(spacer)
$tab()$get(headline)User Info$tab()$char(10)

$puts(size,5)
$if($strcmp(1,$get(trackgain)),$if(%__replaygain_track_gain%,$get(info)RG Track: $get(text)$cut(%__replaygain_track_gain%,$get(size)) dB$char(10)))
$if($strcmp(1,$get(albumgain)),$if(%__replaygain_album_gain%,$get(info)RG Album: $get(text)$cut(%__replaygain_album_gain%,$get(size)) dB$char(10)))

$puts(_rating,$repeat($get(rating_char),%rating%))
$if($strcmp(1,$get(rating)),$if(%rating%,$get(info)Rating: $get(text) $get(_rating) $get(grayed)'('%rating%')'$char(10)))

$if($strcmp(1,$get(play_counter)),$if(%play_counter%,$get(info)Played $get(text)%play_counter%$get(info) times.$char(10)))

$puts(first_played_year,$substr(%first_played%,1,4))
$puts(first_played_month,$substr(%first_played%,6,7))
$puts(first_played_day,$substr(%first_played%,9,10))
$puts(first_played_hour,$substr(%first_played%,12,13))
$puts(first_played_min,$substr(%first_played%,15,16))
$puts(first_played_sec,$substr(%first_played%,18,19))

$if($strcmp(1,$get(first_played_scheme_time)),
$puts(first_played_time,'('$get(first_played_hour):$get(first_played_min):$get(first_played_sec)')')

// DMY
$if($strcmp(1,$get(first_played_scheme)),
$puts(first_played_scheme,$get(first_played_day) / $get(first_played_month) / $get(first_played_year)))

// MDY
$if($strcmp(2,$get(first_played_scheme)),
$puts(first_played_scheme,$get(first_played_month) / $get(first_played_day) / $get(first_played_year)))

// YMD
$if($strcmp(3,$get(first_played_scheme)),
$puts(first_played_scheme,$get(first_played_year) / $get(first_played_month) / $get(first_played_day)))

// YDM
$if($strcmp(4,$get(first_played_scheme)),
$puts(first_played_scheme,$get(first_played_year) / $get(first_played_day) / $get(first_played_month)))

$if($strcmp(1,$get(first_played)),$if(%first_played%,$get(info)First played: $get(text)$get(first_played_scheme) $if($strcmp(1,$get(first_played_scheme_time)), $get(grayed)$get(first_played_time))$char(10))))

$puts(last_played_year,$substr(%last_played%,1,4))
$puts(last_played_month,$substr(%last_played%,6,7))
$puts(last_played_day,$substr(%last_played%,9,10))
$puts(last_played_hour,$substr(%last_played%,12,13))
$puts(last_played_min,$substr(%last_played%,15,16))
$puts(last_played_sec,$substr(%last_played%,18,19))

$if($strcmp(1,$get(last_played_scheme_time)),
$puts(last_played_time,'('$get(last_played_hour):$get(last_played_min):$get(last_played_sec)')')

// DMY
$if($strcmp(1,$get(last_played_scheme)),
$puts(last_played_scheme,$get(last_played_day) / $get(last_played_month) / $get(last_played_year)))

// MDY
$if($strcmp(2,$get(last_played_scheme)),
$puts(last_played_scheme,$get(last_played_month) / $get(last_played_day) / $get(last_played_year)))

// YMD
$if($strcmp(3,$get(last_played_scheme)),
$puts(last_played_scheme,$get(last_played_year) / $get(last_played_month) / $get(last_played_day)))

// YDM
$if($strcmp(4,$get(last_played_scheme)),
$puts(last_played_scheme,$get(last_played_year) / $get(last_played_day) / $get(last_played_month)))

$if($strcmp(1,$get(last_played)),$if(%last_played%,$get(info)Last played: $get(text)$get(last_played_scheme) $if($strcmp(1,$get(last_played_scheme_time)), $get(grayed)$get(last_played_time))$char(10))))
$if($strcmp(2,$get(last_played)),$if(%last_played%,$get(info)Last played: $get(text)$get(nat_lang_stamp)$char(10))))
)
// End User Info

//////////////////////////////
// Tech Info
//////////////////////////////
$if($strcmp(1,$get(show_techinfo)),
$get(spacer)
$tab()$get(headline)Tech Info$tab()$char(10)

$if($strcmp(1,$get(codec)),$get(info)Codec: $get(text)%__codec%
$if($strcmp(1,$get(extra_info)),$get(grayed)'['$if($stricmp(%__extrainfo%,vbr),VBR,CBR)']')
$char(10))

$if($strcmp(1,$get(lame_version)),$if(%__lame_version%,$get(info)LAME: $get(text)%__lame_version% $if($strcmp(1,$get(lame_profile)),$if(%__lame_profile%, %__lame_profile%)) $char(10)))
$if($strcmp(1,$get(mpc_profile)),$if(%__mpc_profile%,$get(info)MPC Profile: $get(text)%__mpc_profile%$char(10)))

$if($strcmp(1,$get(bitrate)),$get(info)Bitrate: $get(text)
$if(%__bitrate_dynamic%,$num(%__bitrate_dynamic%,3) Kbit/s,%__bitrate% Kbit/s)$char(10))

$if($strcmp(1,$get(samplerate)),$get(info)Samplerate: $get(text)$if($strcmp(1,$get(samplerate_short)),$div(%__samplerate%,1000).$substr(%__samplerate%,3,3) kHz,%__samplerate% Hz)$char(10))

$if($strcmp(1,$get(channels)),$get(info)Channels: $get(text)$if(%__channels%,$ifgreater(%__channels%,2,%__channels%,$ifgreater(%__channels%,1,Stereo,Mono)))$char(10))
$if($strcmp(1,$get(bitdepth)),$if(%__bitspersample%,$get(info)Bitdepth: $get(text)%__bitspersample%$char(10)))
$if($strcmp(1,$get(time_elapsed_total)),$get(info)Time: $get(text)$if(%_time_elapsed%,%_time_elapsed% / %_time_total%,%_length%)$char(10))

$if($strcmp(1,$get(encodedby)),$if(%encodedby%,$get(info)Encoded by: $get(text)%encodedby%$char(10)))
$if($strcmp(1,$get(encodersettings)),$if(%encodersettings%,$get(info)Encoder Settings: $get(text)%encodersettings%$char(10)))

$puts(ModSize,$muldiv($mod(%_filesize%,1048576),100,1048576))
$if($strcmp(1,$get(filesize)),$get(info)Filesize: $get(text)$div(%_filesize%,1048576).$ifgreater($get(ModSize),99,99,$num($get(ModSize),2)) MB$char(10))
$if($strcmp(1,$get(filename_ext)),$get(info)File: $get(text)%_filename_ext%$char(10))
$if($strcmp(1,$get(mediatype)),$if(%mediatype%,$get(info)Mediatype: $get(text)%mediatype%$char(10)))
$if($strcmp(1,$get(size)),$if(%size%,$get(info)Size: $get(text)%size%$char(10)))
$if($strcmp(1,$get(songlen)),$if(%songlen%,$get(info)Length: $get(text)%songlen%$char(10)))
$if($strcmp(1,$get(time)),$if(%time%,$get(info)Time: $get(text)%time%$char(10)))
)
// End Tech Info

//////////////////////////////
// Web Info
//////////////////////////////
$if($strcmp(1,$get(show_webinfo)),
$if($if(%wwwaudiofile%,$and($strcmp(1,$get(wwwaudiofile))))
|$if(%wwwcopyright%,$and($strcmp(1,$get(wwwcopyright))))
|$if(%wwwcommercialinfo%,$and($strcmp(1,$get(wwwcommercialinfo))))
|$if(%wwwpayment%,$and($strcmp(1,$get(wwwpayment))))
|$if(%wwwpublisher%,$and($strcmp(1,$get(wwwpublisher))))
|$if(%wwwuser%,$and($strcmp(1,$get(wwwuser))))
|$if(%wwwradiopage%,$and($strcmp(1,$get(wwwradiopage))))
|$if(%netradioowner%,$and($strcmp(1,$get(netradioowner))))
|$if(%netradiostation%,$and($strcmp(1,$get(netradiostation))))
,$get(spacer)

//////////////////////////////
// Web Related
//////////////////////////////
$if($strcmp(1,$get(show_webrelated)),
$if($if(%wwwaudiofile%,$and($strcmp(1,$get(wwwaudiofile))))
|$if(%wwwcopyright%,$and($strcmp(1,$get(wwwcopyright))))
|$if(%wwwcommercialinfo%,$and($strcmp(1,$get(wwwcommercialinfo))))
|$if(%wwwpayment%,$and($strcmp(1,$get(wwwpayment))))
|$if(%wwwpublisher%,$and($strcmp(1,$get(wwwpublisher))))
|$if(%wwwuser%,$and($strcmp(1,$get(wwwuser))))
,
$tab()$get(headline)Web Info$tab()$char(10)
$if($strcmp(1,$get(wwwaudiofile)),$if(%wwwaudiofile%,$get(info)File: $get(text)%wwwaudiofile%$char(10)))
$if($strcmp(1,$get(wwwcopyright)),$if(%wwwcopyright%,$get(info)© $get(text)%wwwcopyright%$char(10)))
$if($strcmp(1,$get(wwwaudiosource)),$if(%wwwaudiosource%,$get(info)Source: $get(text)%wwwaudiosource%$char(10)))
$if($strcmp(1,$get(wwwcommercialinfo)),$if(%wwwcommercialinfo%,$get(info)Info: $get(text)%wwwcommercialinfo%$char(10)))
$if($strcmp(1,$get(wwwpayment)),$if(%wwwpayment%,$get(info)Payment: $get(text)%wwwpayment%$char(10)))
$if($strcmp(1,$get(wwwpublisher)),$if(%wwwpublisher%,$get(info)Publisher: $get(text)%wwwpublisher%$char(10)))
$if($strcmp(1,$get(wwwuser)),$if(%wwwuser%,$get(info)User: $get(text)%wwwuser%$char(10)))
$char(10))
)
// End Web Info

//////////////////////////////
// Net Radio Info
//////////////////////////////
$if($strcmp(1,$get(show_netradioinfo)),

$if($if(%wwwradiopage%,$and($strcmp(1,$get(wwwradiopage))))
|$if(%netradioowner%,$and($strcmp(1,$get(netradioowner))))
|$if(%netradiostation%,$and($strcmp(1,$get(netradiostation))))
,$tab()$get(headline)NetRadio Info$tab()$char(10)
$if($strcmp(1,$get(wwwradiopage)),$if(%wwwradiopage%,$get(info)Page: $get(text)%wwwradiopage%$char(10)))
$if($strcmp(1,$get(netradioowner)),$if(%netradioowner%,$get(info)Owner: $get(text)%netradioowner%$char(10)))
$if($strcmp(1,$get(netradiostation)),$if(%netradiostation%,$get(info)Station: $get(text)%netradiostation%$char(10))))
)))
// End - Web Related

//////////////////////////////
// Misc Info
//////////////////////////////
$if($strcmp(1,$get(show_miscinfo)),
$if($if(%subtitle%,$and($strcmp(1,$get(subtitle))))
|$if(%involvedpeople%,$and($strcmp(1,$get(involvedpeople))))
|$if(%playlistdelay%,$and($strcmp(1,$get(playlistdelay))))
|$if(%initialkey%,$and($strcmp(1,$get(initialkey))))
|$if(%isrc%,$and($strcmp(1,$get(isrc))))
|$if(%partinset%,$and($strcmp(1,$get(partinset))))
,$get(spacer)
$tab()$get(headline)Misc Info$tab()$char(10)
$if($strcmp(1,$get(subtitle)),$if(%subtitle%,$get(info)Subtitle: $get(text)%subtitle%$char(10)))
$if($strcmp(1,$get(involvedpeople)),$if(%involvedpeople%,$get(info)Involved People: $get(text)%involvedpeople%$char(10)))
$if($strcmp(1,$get(playlistdelay)),$if(%playlistdelay%,$get(info)Playlistdelay: $get(text)%playlistdelay%$char(10)))
$if($strcmp(1,$get(initialkey)),$if(%initialkey%,$get(info)Initialkey: $get(text)%initialkey%$char(10)))
$if($strcmp(1,$get(isrc)),$if(%isrc%,$get(info)ISRC: $get(text)%isrc%$char(10)))
$if($strcmp(1,$get(partinset)),$if(%partinset%,$get(info)Partinset: $get(text)%partinset%$char(10)))
))
// End Misc Info

//////////////////////////////
// Original Info
//////////////////////////////
$if($strcmp(1,$get(show_originalinfo)),
$if($if(%origartist%,$and($strcmp(1,$get(origartist))))
|$if(%origyear%,$and($strcmp(1,$get(origyear))))
|$if(%origlyricist%,$and($strcmp(1,$get(origlyricist))))
|$if(%origfilename%,$and($strcmp(1,$get(origfilename))))
,$get(spacer)
$tab()$get(headline)Original Info$tab()$char(10)
$if($strcmp(1,$get(origartist)),$if(%origartist%,$get(info)Artist: $get(text)%origartist%$char(10)))
$if($strcmp(1,$get(origyear)),$if(%origyear%,$get(info)Year: $get(text)%origyear%$char(10)))
$if($strcmp(1,$get(origlyricist)),$if(%origlyricist%,$get(info)Lyricist: $get(text)%origlyricist%$char(10)))
$if($strcmp(1,$get(origfilename)),$if(%origfilename%,$get(info)Filename: $get(text)%origfilename%$char(10)))
))
PaVliG
Новичок
Репутация: 0
С нами: 12 лет 9 месяцев

Сообщение #57 deff » 06.05.2007, 18:36

Alex 'AJ' Jade писал(а):Track Info Mod обновляется автоматически (в последней версии этого почему то не происходит! Изображение).
а раздел// PerSecond не пробовали создовать?  :)
deff M
Бывалый
Аватара
Возраст: 32
Откуда: Якутск
Репутация: 0
С нами: 12 лет 8 месяцев

Сообщение #58 mgz » 12.06.2007, 20:55

Panels_UI научился поддерживать %foobar_path%.
RME HDSP 9632 > DynAudio BM5A II / Audio-Technica ATH-AD900
Nexus 5 > Avantree Clipper > Sennheiser IE 4
mgz M
Гуру
Аватара
Возраст: 39
Откуда: Украина, Киев
Репутация: 73
С нами: 13 лет 4 месяца

Сообщение #59 Lite » 18.06.2007, 00:04

mgz писал(а):Panels_UI научился поддерживать %foobar_path%.

у меня что-то не хочет работать с этим тагом, хотя версия 0.13.8.beta[br]Написано: 17 Июня 2007, 23:57а нет все нормально, заработало
Lite M
Бывалый
Аватара
Возраст: 43
Откуда: С-Петербург
Репутация: 0
С нами: 13 лет 4 месяца

Сообщение #60 mgz » 18.06.2007, 13:48

2Lite
У меня выводит путь в Главном Layout (там где панели расставлены), и внутри панели Track Display, и в SCP.
На данный момент стоит версия 0.13.7.
Изображение
RME HDSP 9632 > DynAudio BM5A II / Audio-Technica ATH-AD900
Nexus 5 > Avantree Clipper > Sennheiser IE 4
mgz M
Гуру
Аватара
Возраст: 39
Откуда: Украина, Киев
Репутация: 73
С нами: 13 лет 4 месяца

Пред.След.

Вернуться в Секреты foobar2000

Кто сейчас на форуме (по активности за 10 минут)

Сейчас этот раздел просматривают: 1 гость