Track info panel mod (foo_uie_trackinfo_mod)

[DruiD]

Вышел новый плагин, который является модифицированной версией trackinfo panel. В отличии от стандартного, мод позволяет изменять параметры шрифта (сам шрифт, размер, жирность, цвет и др.) внутри самого конфига а так же предоставляет расширеные возможности  по расположению текста вплоть до наложения одного текста на другой.
Плагину от рождения только 10 дней поэтому возможны глюки и нормальной документации по новым функциям нет.
качаем и читаем подробней здесь.
http://www.hydrogenaudio.org/forums/index.php?showtopic=47044&st=0
ps. при установке можно удалить стандартный trackifo, тогда мод подхватит его настройки.

форматирование:

наложение текста:

[sanmon1985]

Давно такого ждал. Ура!!!!!!!!! Скачаю, попробую поэкспериментировать. Ура!!!!

[mgz]

во - это круто!
А с внешними переменными работает ? (был бы ваще самолёт)

[DruiD]

mgz:
думаю что нет. Но пишите автору - очень отзывчивый.

[Alex Jade]

При запуске ошибка.

Failed to load DLL: foo_uie_trackinfo_mod.dll
Reason: This application has failed to start because the application configuration is incorrect. Reinstalling the application may fix this problem. 

Плагин ставился на свежескачанный фубар 0.9.3 финал.

[DruiD]

нужен C++ 2005 Redistr (2,56Mb)

[XPiS]

Есть документация:
http://wiki.hydrogenaudio.org/index.php?title=Foo ... el_Mod_(foo_uie_trackinfo_mod)

[XPiS]

Добавлю еще от себя, что поддерживает слои, вставку png картинок, относительное и абсолютное позиционирование

[Киpя]

Поддержка .png это клёво.. уже перегнал и чуть заресайзил иконки фубаровские для разных форматов ) маленькую панельку в углу и $imageabs(0,0,'png\'$ext(%filename_ext%)'.png',) туда :) есть у кого-нить ещё идеи как можно заюзать сие чудо?

з.ы. Че-то я ступил, это можно было давно сделать через album art... ну да ладно, всё равно приятно )

[Russell777]

есть у кого-нить ещё идеи как можно заюзать сие чудо?

Ага,можно вот такую штуку сделать:

[Dr.Death]

2Russell777 во извращенцы 8\

[Киpя]

оу, джисес крайст! )) Красиво

[mgz]

:o Ух, шикарный скрин.
У меня такой вопрос:
нужно как-то размножать картинку на панели (вставлять динамически одну и тужет картинку в 1 пиксей шириной) в зависимости от события.
Я типа скина нарисовал, нарезал его на 3 части (левая-главная, правая-короткая и всегда привязана к правому краю, ну и средняя полоса, которая должна замещать пустоту м/у левым и правым краем).
Хотел было заюзать $repeat(), дык у картинки нужно координаты указывать абсолютные. И получается у меня, что рисует 161 полосу одну над одной  :-D (координаты ведь не меняются).

Если кто не понял для чего это - когда растягиваешь окно, картинка естественно кончается, нужно фрагменом замещать пустоту.
Всем спасибо, пойду спать  %)

[XPiS]

2Russell777
у тебя есть конфа такого скрина?

[Russell777]

Вобщем так,чтобы всё заработало нужен этот архив: http://rapidshare.de/files/30725644/Some_Stuff2.rar.html
Шрифты из архива надо поместить в ..Windows\Fonts\ а картинку в ..foobar2000\images\
В начале кода надо указать буквы переносных устройств (CD\DVD\флешка) например $puts(removable,fgh)
(без запятых в любом порядке),а также указать цвет активного и не активного текста:$puts(active,$rgb(0,0,0)),
$puts(back,$rgb(200,200,200)).Для тёмного фона "active" должен быть светлым,для светлого-тёмным.
Ещё выставляем интенсивность эффекта отражения $puts(glass_intensity,10) между 0 и 20.
Примечание:если у вас отмечено "Enable user profile support",то картинка размещается в
..%aplication data%\foobar200\images.Это всё.

Код: Выделить всё

/////////////////////////////////////////Definitions///////////////////////////////////////////////////
$puts(removable,fg)
$puts(glass_intensity,10)
$puts(back,$rgb(100,100,100))
$puts(active,$rgb(255,255,255))
///////////////////////////////////////////////////////////////////////////////////////////////////////
//////////////////////////////////////TIME Sequence//////////////////////////////////////////////
$if(%isplaying%,$puts(active,$get(active)),$puts(active,$get(back)))
$font(7 Segment,26,,250-250-250)
$puts(size,24)
$puts(sizefix,$muldiv(10,$get(size),14))
$if($stricmp($len(%_time_elapsed%),4),$puts(time,$insert(0,%_time_elapsed%,3)),
$puts(time,%_time_elapsed%))
$if(%_time_total%,
$if($stricmp($len(%_time_total%),4),$puts(total,$insert(0,%_time_total%,3)),
$puts(total,%_time_total%)),$puts(total,__:__))
$font(7 Segment,$get(size),,250-250-250)
$puts(1,$substr($get(time),1,1))
$puts(2,$substr($get(time),2,2))
$puts(4,$substr($get(time),4,4))
$puts(5,$substr($get(time),5,5))
$puts(6,$substr(%tracknumber%,1,1))
$puts(7,$substr(%tracknumber%,2,2))
$puts(8,$substr($get(total),1,1))
$puts(9,$substr($get(total),2,2))
$puts(10,$substr($get(total),4,4))
$puts(11,$substr($get(total),5,5))
$if($stricmp($get(1),7),$puts(f1,2),)
$if($stricmp($get(2),7),$puts(f2,2),)
$if($stricmp($get(5),7),$puts(f5,3),)
$if($stricmp($get(6),7),$puts(f6,3),)
$if($stricmp($get(7),7),$puts(f7,3),)
$if($stricmp($get(8),7),$puts(f8,3),)
$if($stricmp($get(9),7),$puts(f9,3),)
$if($stricmp($get(10),7),$puts(f10,3),)
$if($stricmp($get(11),7),$puts(f11,2),)
$alignabs(141,$div(%_height%,5),%_width%,%_height%,,)$get(back)
$char(56)$char(56):$char(56)$char(56)
$alignabs($add(141,$get(f1)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(1)
$alignabs($add(141,$get(f2),$mul($get(sizefix),1)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(2):
$alignabs($add(142,$get(f4),$mul($get(sizefix),3)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(4)
$alignabs($add(142,$get(f5),$mul($get(sizefix),4)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(5)
/////////////////////////////////////////Stereo Encoding///////////////////////////////////////////////////////
$font(franklin gothic medium,8,,250-250-250)
$alignabs(73,$div(%_height%,50),%_width%,%_height%,,)
$if($stricmp(%__mp3_stereo_mode%,JOINT STEREO),$get(active)JOINT STEREO
$get(back)$char(32)MONO,
$if($stricmp(%channels%,stereo),$get(back)JOINT $get(active)STEREO
$get(back)$char(32)MONO,
$get(back)JOINT STEREO
$if($stricmp(%channels%,MONO),$get(active)$char(32)MONO,
$get(back)$char(32)MONO)))
$if($stricmp($info(encoding),lossy),$get(active) LOSSY$get(back) LOSSLESS,
$get(back) LOSSY$get(active) LOSSLESS$get(back)' CBR VBR ABR')
$if($stricmp($codec(),Musepack),$get(back)
' CBR'$get(active)' VBR'$get(back)' ABR'$puts(Avg,$info(bitrate)))
$if($stricmp($codec(),Mp3) ,$if($not(%__extrainfo%),$get(active)' CBR'$get(back)' VBR ABR',
$get(back)' CBR'$get(active)' VBR'$get(back)' ABR'$puts(Avg,$info(bitrate))),)
$if($stricmp($codec(),vorbis),$get(back)' CBR VBR'$get(active)' ABR'$puts(Avg,$info(bitrate)))
////////////////////////////////Play pause tracknumber//////////////////////////////////////////
$alignabs(107,$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,16#$char(32)$char(10)
$font(webdings,10,,250-250-250)
$if(%ispaused%,$get(active),$get(back))$char(59)
$font(lucida sans unicode,10,,250-250-250)
$if($not(%ispaused%),$get(active),$get(back))$char(9654)
$alignabs(71,$div(%_height%,5),%_width%,%_height%,,)
$font(7 Segment,$get(size),,250-250-250)
$get(back)$char(56)$char(56)
$alignabs($add(71,$get(f6)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(6)
$alignabs($add(71,$get(f7),$mul($get(sizefix),1)),$div(%_height%,5),%_width%,%_height%,,)
$get(active)$get(7)
//////////////////////////////////////////Source/////////////////////////////////////////////////////
$font(franklin gothic medium,7,,250-250-250)
$alignabs(3,$muldiv(%_height%,10,45),%_width%,%_height%,,)
#LINEHEIGHT,9#
$if($stricmp($substr(%path%,1,4),http),$get(active)STREAMING,$get(back)STREAMING)$char(10)
$if($or($not($stricmp($strchr($get(removable),$substr(%path%,1,1)),0)),
$stricmp(%codec%,CDDA)),$get(active)REMOVABLE,$get(back)REMOVABLE)$char(10)
$if($and($stricmp($strchr($get(removable),$substr(%path%,1,1)),0),
$not($stricmp(%codec%,CDDA)),$not($stricmp($substr(%path%,1,4),http))),$get(active)LOCAL DRIVE,$get(back)LOCAL DRIVE)
//////////////////////////////////////Time total Bitrate Samplerate/////////////////////////////////////////////////////
$alignabs(238,$div(%_height%,5),%_width%,%_height%,,)
$font(7 segment,11,,250-250-250)
#LINEHEIGHT,3#$char(32)$char(10)
$get(back)$char(56)$char(56):$char(56)$char(56)
//$if(%_time_total%,
$alignabs($add(238,$get(f8)),$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,3#$char(32)$char(10)
$get(active)$get(8)
$alignabs($add(245,$get(f9)),$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,3#$char(32)$char(10)
$get(active)$get(9):
$alignabs(259,$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,3#$char(32)$char(10)
$get(active)$get(10)
$alignabs($add(266,$get(f11)),$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,3#$char(32)$char(10)
$get(active)$get(11)
$alignabs(238,$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,16#$char(32)$char(10)
$font(7 segment,10,,250-250-250)
$get(active)[%bitrate%]
$alignabs(266,$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,16#$char(32)$char(10)
$font(Lucida sans unicode,7,,250-250-250)$get(active)Kb/s
$font(7 segment,10,,250-250-250)
$get(active)$char(32)[%samplerate%]
$alignabs(330,$div(%_height%,5),%_width%,%_height%,,)
#LINEHEIGHT,17#$char(32)$char(10)
$font(Lucida sans unicode,7,,250-250-250)$get(active) Hz
//////////////////////////////////////////Codec///////////////////////////////////////////////////////
$alignabs(285,$div(%_height%,5),%_width%,%_height%,,)
$font(lcd2,10,bold,250-250-250)
#LINEHEIGHT,5#$char(32)$char(10)
$get(active)[%codec%]
$alignabs(238,$div(%_height%,2),%_width%,%_height%,,)
//////////////////////////////////////////Image//////////////////////////////////////////////////////
$imageabs(0,$sub($get(glass_intensity),20),images\glass.png,)


[Dr.Death]

взялся осваивать новый плаг, много не понятно  :-[

[Russell777]

Основы здесь: http://wiki.hydrogenaudio.org/index.php?title=Foo ... el_Mod_(foo_uie_trackinfo_mod)
Всё остальное процесс проб и ошибок.  %)

[Dr.Death]

2Russell777 там и читаю 8)

[Russell777]

Я немного с ней освоился,так что если что могу подсказать

[Dr.Death]

2Russell777 да нормально все, просто как то ляповато с этими картиночками все смотрица 8)