evil_foobar2000_v1.4_2020-06-06

[evil]

Сборка
foobar2000_evil_v1.4 (19.10 Mб)
Скачать:

https://yadi.sk/d/yFa8RK4IA0ae8A

Внешний вид, скриншот: https://yadi.sk/i/fgOR2Aq8hwT4UQ

Описание

evil_v6.3.fcl - основная конфигурация для Columns UI, разделение по альбомам, имеет около 30 цветовых схем (в т.ч. и светлые).
evil_new_v1.33.fcl - новая конфигурация для Columns UI, представлена на скриншоте.
evil_plain_v3.1.fcl - плоское форматирование без выделения альбомов, имеет несколько цветовых схем.
evil_minna_v2.2.fcl - альтернативная конфигурация.
evil_v1.0.fth - тема для Default UI, единая группировка Advanced для альбомов и единичных треков.


FAQ

• Основная информация находится в файле readme.htm, который расположен в корне установленного foobar2000.
• Как менять цветовые схемы.
• Как обновиться без потерь (библиотека, счётчик, рейтинг).
• Каким образом можно облегчить сборку?

* * *

Сборка
foobar2000_evil_v0.8.3 (2.8 Mб)
Скачать:

https://yadi.sk/d/MkKnwfW43Tv4tD

Внешний вид, скриншот:
https://yadi.sk/i/S2Nn7UJVrhmeV

[John Dee]

прошу помочь всё с тем же performer, можно ли исправить это не удаляя тег?

[evil]

2John Dee
Как и чем заполнены теги?

[John Dee]

выглядит это так , а заполнено MusicBrainz Picard

[evil]

2John Dee
Предложи алгоритм для отображения artist, album artist, performer.

[John Dee]

мне не нужно, чтобы перформер отображался... это всё что я могу сказать  :)

[evil]

2John Dee
В данном альбоме или никогда?

[John Dee]

никогда, мне вообще не нужно чтобы performer отображался где-либо,

[evil]

2John Dee
Проверь такой скрипт для колонки ArtistAlbumTitle:

Код: Выделить всё

//ЕСЛИ ЕСТЬ НОМЕРА ТРЕКОВ
$if($and(%tracknumber%,$not($get_global(random))),

//определение режима форматирования строк плейлиста (параметр находится в Globals - Variables - layout_mode)
$ifequal($get_global(layout_mode),0,

//ЕСЛИ УСТАНОВЛЕН РЕЖИМ ПОЛНОГО ФОРМАТИРОВАНИЯ. НАЗВАНИЕ КОМПОЗИЦИИ ОТДЕЛЯЕТСЯ ТАБУЛЯЦИЕЙ ОТ ИМЕНИ ИСПОЛНИТЕЛЯ.

//исполнитель, автор (первая строка в альбоме). формат artist
$if($stricmp($sub(%tracknumber%,1),0),
$if($meta(album artist),$if(%isplaying%,$get_global(t21),$get_global(t2))$ifequal($get_global(use_caps),0,$meta(album artist),$caps2($meta(album artist))),
$if($get_global(va),$if(%isplaying%,$get_global(t21),$get_global(t2))$get_global(va_string),
$if($meta(artist),$if(%isplaying%,$get_global(t21),$get_global(t2))$ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%)),
//если audio-cd без тегов
$if($get_global(cdda),'Audio CD',
'Unknown ARTIST'))
)),

//альбом, год (вторая строка в альбоме). формат 'album (date)'
$if($stricmp($sub(%tracknumber%,1),1),
$if(%album%,$if(%isplaying%,$get_global(t101),$get_global(t10))$ifequal($get_global(use_caps),0,%album%,$caps2(%album%))$ifgreater(%totaldiscs%,1,[' 'CD%discnumber%],)[' ('%date%')'],'Unknown ALBUM')
,

//жанр (третья строка в альбоме). формат genre
$if($stricmp($sub(%tracknumber%,1),2),
$if(%isplaying%,$get_global(t31),$get_global(t3))$if(%genre%,$ifequal($get_global(use_caps),0,%genre%,$caps2(%genre%)),'Unknown GENRE'))))

$tab(2)
,

//ЕСЛИ УСТАНОВЛЕН РЕЖИМ КОМПАКТНОГО ФОРМАТИРОВАНИЯ. НАЗВАНИЕ КОМПОЗИЦИИ НЕ ОТДЕЛЯЕТСЯ ТАБУЛЯЦИЕЙ ОТ ИМЕНИ ИСПОЛНИТЕЛЯ.

//исполнитель, автор. формат artist
$if($meta(album artist),$if(%isplaying%,$get_global(t21),$get_global(t2))$ifequal($get_global(use_caps),0,$meta(album artist),$caps2($meta(album artist))),
$if($get_global(va),$if(%isplaying%,$get_global(t21),$get_global(t2))$get_global(va_string),
$if($meta(artist),$if(%isplaying%,$get_global(t21),$get_global(t2))$ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%)),
//если audio-cd без тегов
$if($get_global(cdda),'Audio CD',
'Unknown ARTIST'))
))' '
)

//ОБЩАЯ ЧАСТЬ
//номера треков с раскраской до 10
$if(%isplaying%,$get_global(t41),$get_global(t4))
'['
$if(%isplaying%,$get_global(t51),$get_global(t5))
$ifgreater(%tracknumber%,9,
$if(%isplaying%,$get_global(t51),$get_global(t5))$num(%tracknumber%,2),
$if(%isplaying%,$get_global(t41),$get_global(t4))'0'$if(%isplaying%,$get_global(t51),$get_global(t5))$num(%tracknumber%,1))
$if(%isplaying%,$get_global(t41),$get_global(t4))
'] '

//ARTIST, PERFORMER
//если есть album artist, то, возможно, VA или если альбом с 'Various Artist'
$if($or($meta(album artist),$get_global(va)),
//если PERFORMER = ARTIST и нет ALBUM ARTIST или ARTIST = ALBUM ARTIST и нет PERFORMER, то не выводить
$if($or($and($stricmp(%performer%,%artist%),$strcmp($meta_num(album artist),0)),$and($stricmp($meta(album artist),$meta(artist)),$strcmp($meta_num(performer),0))),
//пусто
,
$if(%artist%,
$if(%isplaying%,$transition($ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%)),$get_global(t7),$get_global(t6)),$get_global(t2)$ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%))),
$get_global(t1)$if(%length%,%directoryname%,'Stream'))
$if(%isplaying%,$ifgreater($mod(%playback_time_seconds%,2),0,$get_global(t8),$get_global(t9)),$get_global(t8))$get_global(separator)
)
,
//иначе обычный альбом, а значит и выводить артиста с разделителем не следует
)

//TITLE
$if(%isplaying%,
//ЕСЛИ ПРОИГРЫВАЕТСЯ
//вывод с плавным переходом цвета
$transition($ifequal($get_global(use_caps),0,%title%,$caps2(%title%)),$get_global(t6),$get_global(t7)),
//ИНАЧЕ, ЕСЛИ НЕ ПРОИГРЫВАЕТСЯ
//вывод с раскраской содержимого скобок
$get_global(t1)$replace($ifequal($get_global(use_caps),0,%title%,$caps2(%title%)),'(',$get_global(t3)'(',')',')'$get_global(t1))
)

$ifequal($get_global(layout_mode),0,
//ПОЛНОЕ ФОРМАТИРОВАНИЕ
$tab(3),
//КОМПАКТНОЕ ФОРМАТИРОВАНИЕ
//альбом с указанием даты. формат 'X' (Y)
$if(%album%,$if(%isplaying%,$get_global(t41),$get_global(t4)) ''$ifequal($get_global(use_caps),0,%album%,$caps2(%album%))$ifgreater(%totaldiscs%,1,[' 'CD%discnumber%],)''[ %date%],)
)
,

//ЕСЛИ НЕТ НОМЕРОВ ТРЕКОВ
//автор, либо имя директории (если тег отсутствует); если играет, то с плавной раскраской
$if(%artist%,
$if(%isplaying%,$transition($ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%)),$get_global(t7),$get_global(t6)),$get_global(t2)$ifequal($get_global(use_caps),0,%artist%,$caps2(%artist%))),
$get_global(t1)$if(%length%,%directoryname%,'Stream'))

//название трека с плавной раскраской (если проигрывается) и текста в скобках (если не проигрывается)
$if(%title%,
$if(%isplaying%,$ifgreater($mod(%playback_time_seconds%,2),0,$get_global(t8),$get_global(t9)),$get_global(t8))$get_global(separator)
//TITLE
$if(%isplaying%,
//ЕСЛИ ПРОИГРЫВАЕТСЯ
//вывод с плавным переходом цвета
$transition($ifequal($get_global(use_caps),0,%title%,$caps2(%title%)),$get_global(t6),$get_global(t7)),
//ИНАЧЕ, ЕСЛИ НЕ ПРОИГРЫВАЕТСЯ
//вывод с раскраской содержимого скобок
$get_global(t1)$replace($ifequal($get_global(use_caps),0,%title%,$caps2(%title%)),'(',$get_global(t3)'(',')',')'$get_global(t1))
)
,)

//альбом с указанием даты (если в настройке выбран показ - Globals - Variables - show_album). формат , album 'X' of Y year
$ifequal($get_global(show_album),0,,
$if(%album%,$if(%isplaying%,$get_global(t41),$get_global(t4))', album '''$ifequal($get_global(use_caps),0,%album%,$caps2(%album%))$ifgreater(%totaldiscs%,1,[' 'CD%discnumber%],)''
$if(%date%,' of '%date%' year',),))
)


В следующей версии его не будет, но возможно предусмотрю такой вариант как настройку.

[John Dee]

спасибо, работает!  *пыво* за лучшую сборку!

[comix19]

При добавлении нового альбома выделение ставиться на него (в свернутом режиме, да и вообще) следовательно текущая прослушка слетает, и следующим треком играет тот который я добавил последний. Думаю легко испрвляеться в настройках... но не могу найти. Хелп :)

Еще вопрос, предусмотрено ли в вашей сборке, что то типо ознакомительного плагина? Хотелось бы такую штуку при включении которой, проигрывалось скажем 30% от общей длинны песни, то есть если надо быстро познакомиться с альбомом скажем. Если ли такое? (Если нету, но знаете о чем речь, прошу помочь с ссылкой на сабж :) )

[evil]

следовательно текущая прослушка слетает... Думаю легко испрвляеться в настройках

Не встречал подобной настройки.

что то типо ознакомительного плагина

Главное меню Playback - Preview mode.

[NecroMan]

2comix19
Скорее всего, стоит галка Playback - Playback Follow Cursor. Убери, выделение больше не будет влиятья на порядок проигрывания.

[Violar]

Уважаемый evil, всплыла новая фича.    Провожу поиск в плейлисте All music, результаты выцепливатся в новый плейлист "Search results: ****"     И при воспроизведении этого списка, проигранные треки исчезают из него.   То есть закончила дорожка играть, начала следующая - а предыдущая самоустраняется из списка. Можно ли это отключить?   В настройках фубара не нашёл намёков на это....   Основной плейлист при этом остаётся в исходном виде.

[evil]

2Violar
Проверь галочку в главном меню Playback - Remove played tracks.

[Violar]

......  *пыво*  а то все preferences облазил.

[Juice25]

Сегодня начал пользоваться данной сборкой, перепробовал много других, эта самая лучшая имхо! Спасибо автору *пыво*

Но вот есть вопросик, извиняюсь если подобный вопрос уже задавался. Как изменить отображение исполнителей в плей-листе? А то вот например есть много альбомов с похожей неприятностью

[img width=400 height=155]http://img717.imageshack.us/img717/4951/snap20100227191538001.png[/img]

У каждой песни свой исполнитель, а он показывает Group Home (исполнитель) для всех. Стандартная функция с VA не подходит. Да и в общем я привык что-бы возле каждой песни отображался исполнитель.

Как можно сделать что-то похожее ? [img width=400 height=155]http://img85.imageshack.us/img85/80/snap20100227192122002.png[/img]

Т.е. что-бы всегда отображался исполнитель, название песни и без последних двух столбцов ? Это как-то надо менять в скрипте?

[evil]

Стандартная функция с VA не подходит

Почему не подходит? Можно увидеть как и чем заполнены теги?

Т.е. что-бы всегда отображался исполнитель

Нужно отображать для VA альбомов или независимо для любых?
Если VA, то нужно заглянуть в readme, раздел Распознавание various artist. Если для любых, то применить evil_plain_v3.01.fcl (как применять - описано в readme, раздел Как применить fcl-файл?). Где найти этот файл? Надо прочитать раздел readme, раздел Расположение исходных файлов настроек для различных компонент.

без последних двух столбцов

Изменить набор колонок можно, прочитав readme, раздел Изменение набора колонок Columns UI в плейлисте.

[Juice25]

2evil нужно отображать независимо для любых

[evil]

2Juice25
Я уже ответил. Сообщение не просто так пропало.

[Juice25]

2evil извиняюсь, не заметил)) Сейчас попробую сделать) Спасибо!